L’ammortamento anticipato di cespiti

di Corrado Del Buono

scritto il

Un metodo automatico per calcolare l'ammortamento dei beni anticipato che consente un'ottimizzazione del reddito imponibile nei primi tre anni.

In questo tutorial viene proposto un modello per la determinazione del piano di ammortamento anticipato di un cespite.

L’ammortamento anticipato è una procedura fiscale che consente di ammortizzare un bene assegnando ad esso, per i primi tre esercizi contabili, il doppio del coefficiente di ammortamento “ordinario” previsto dalla tabella ministeriale del Ministero dell’Economia per le diverse tipologie di cespiti.

Attraverso tale sistema di calcolo, la normativa fiscale tende ad agevolare le aziende in quanto viene “posticipato” nel tempo, il pagamento delle imposte.

Modello per l'ammortamento anticipato
scarica il modello di calcolo per l’ammortamento anticipato di cespiti

Di fatto, il raddoppio del coefficiente di ammortamento nei primi tre anni di vita del cespite consente di imputare a tali esercizi un costo maggiore (l’ammortamento). Di conseguenza, a parità di ricavi, è possibile ottenere un reddito imponibile minore

Il “recupero” dell’imposizione fiscale avviene negli ultimi anni di vita del cespite quando, a seguito del maggiore ammortamento già imputato al bene, si avranno dei valori di ammortamento più bassi e, quindi, un maggior reddito fiscale.

=>Confronta con l’ammortamento ordinario di cespiti

Come utilizzare il modello

L’utilizzazione del modello è molto semplice in quanto è sufficiente inserire nella cella A4 una breve descrizione del bene, nella cella D5 il costo da ammortizzare, nella cella D6 il primo esercizio contabile di riferimento ed, infine, nella cella D7 il coefficiente ministeriale di ammortamento; al termine dell’inserimento dei dati viene elaborato automaticamente il piano di ammortamento nella tabella sottostante.

Figura 1. Esempio di compilazione del modello

Esempio di compilazione del modello

La formula, dalla struttura simile a quella precedente, tiene conto della percentuale cumulata dei coefficienti di ammortamento dei due anni precedenti; difatti, nel terzo anno di riferimento, occorre testare se il valore già ammortizzato in precedenza (SOMMA($G$10:G11)) non superi il coefficiente massimo (100%) di ammortamento.

L’assegnazione di un “riferimento assoluto” alla cella G10 interna alla funzione SOMMA, consente di copiare la formula fino alla cella C59; in questo modo nel quarto esercizio contabile si terrà conto della percentuale di ammortamento cumulata fino al terzo anno (SOMMA($G$10:G12)), nel quinto esercizio di quella cumulata fino al quarto anno, e così a seguire.

Quando non si verifica più la condizione della funzione SE della formula, ovvero quando la differenze tra 100% e la somma delle percentuali di ammortamento assegnate al cespite è inferiore del coefficiente di ammortamento ordinario (D7), la formula restituirà il valore residuo da ammortizzare, mentre, dall’esercizio contabile successivo, poiché la somma delle percentuali cumulate è pari al 100%, restituirà uno zero (0%).

Le formule utilizzate fino ad ora consentono di mantenere il prospetto “flessibile”, ovvero di adattare automaticamente il suo contenuto in base al coefficiente digitato nella cella D7, senza ricorrere alle “colonne di servizio” utilizzate nella costruzione del modello relativo all’ammortamento ordinario.

=> Approfondisci il bilancio aziendale: ammortamento delle immobilizzazioni

Difatti l’esercizio contabile (celle della colonna A) viene visualizzato a condizione che esista un valore maggiore di zero nella corrispondente cella della colonna G; queste ultime, sommando le percentuali di ammortamento ordinario e anticipato, anno per anno, visualizzeranno un valore maggiore di zero fino a quando è presente un coefficiente di ammortamento nelle corrispondenti celle della colonna C; in queste ultime, infine, verrà visualizzato un valore fino all’esercizio contabile nel quale la percentuale cumulata di ammortamento ha raggiunto il 100%!

Per richiamare il coefficiente di ammortamento anticipato relativo al primo anno, nella cella E10 è stata utilizzata la formula =C10. Nelle due celle sottostanti sono state utilizzate formule dalla sintassi simile a quelle inserite nella colonna C.

In particolare, nella cella E11 è stata trascritta la formula

=SE(100%-G10-C11>$D$7;C11;100%-G10-C11)

che può essere letta in questo modo: se la differenza tra 100% e il coefficiente di ammortamento complessivo (ordinario e anticipato) del primo anno (G10) sommato al coefficiente ordinario del secondo anno (C11) è maggiore del coefficiente di ammortamento ministeriale (D7), trascrivi il coefficiente ordinario (C11) altrimenti restituisci il valore residuale (100%-G10-C11).

Nella cella E12 è stata utilizzata la formula

=SE(100%-(G10+G11)-C12>$D$7;C12;100%-(G10+G11)-C12)

simile a quella precedente, ma che tiene conto della percentuale cumulata (G10+G11) dei coefficienti utilizzati nei primi due esercizi contabili.

Da notare che queste ultime due formule, che a prima vista potrebbero sembrare “superflue” (si potrebbe, infatti, pensare di utilizzare soltanto il riferimento alle celle C11 e C12) sono necessarie per ammortizzare correttamente quei beni per i quali è previsto un coefficiente di ammortamento superiore al 20% (in questi casi, difatti, poiché il cespite viene ammortizzato completamente nei primi tre anni, risulterebbe non corretto il riferimento alle celle C11 e C12).

La parte restante del prospetto richiama e/o calcola i valori contabili relativi al bene.

Nella cella B10 è stata utilizzata la formula =SE(A10=””;0;$D$5) che consente la trascrizione del costo storico del cespite (D5) a condizione che la cella alla sua sinistra (A10) non sia vuota, ovvero contenga l’esercizio contabile di riferimento.

=> Leggi gli altri tutorial con Excel

Per determinare la quota di ammortamento ordinario, nella cella D10 è stata utilizzata la formula =ARROTONDA(B10*C10;2) che arrotonda a due cifre decimali il valore che scaturisce dalla moltiplicazione tra il costo storico (B10) e la percentuale di ammortamento ordinario (C10).

Entrambe le formule sono state successivamente copiate verso il basso fino alla riga 59.

Nella cella F10 è stata utilizzata la formula =ARROTONDA(B10*E10;2) che consente, come quella precedente, di arrotondare a due cifre decimali il valore che scaturisce dal costo storico per la percentuale di ammortamento anticipato. La formula è stata copiata nelle due celle sottostanti per determinare la quota di ammortamento anticipato nei primi tre esercizi contabili.

Figura 3. Esempio dell’arrotondamento per i primi 3 esercizi contabili

Esempio dell'arrotondamento per i primi 3 esercizi contabili

Per determinare l’ammortamento relativo al primo esercizio contabile si è utilizzata nella cella H10 la formula =ARROTONDA(B10*G10;2) che arrotonda la moltiplicazione tra il costo storico del cespite (B10) e la percentuale complessiva di ammortamento (ordinario più anticipato); la formula è stata successivamente copiata verso il basso fino alla cella H59.

Per calcolare il valore da iscrivere nel Fondo ammortamento si è utilizzata, nella cella I10 la formula =H10 (il fondo di ammortamento relativo al primo anno coincide con il valore ammortizzato), mentre nella cella I11 la formula =SE(G11>0;I10+H11;0); quest’ultima, successivamente copiata fino alla cella I59, restituisce la somma del valore del fondo di ammortamento pregresso (nello specifico, contenuto nella cella sovrastante I10) con il valore dell’ammortamento annuale del cespite (contenuto nella cella H11) se, nell’esercizio contabile in corso, non si è esaurita la percentuale di ammortamento da applicare al bene (G11>0).

Infine, nella cella J10, è stata utilizzata la formula =B10-I10 per la determinazione del valore residuo da ammortizzare (anche questa formula è stata copiata fino alla cella J59).

Come personalizzare il modello

Il modello è stato costruito con cinquanta righe in maniera da poter visualizzare correttamente il piano di ammortamento di quasi la totalità dei cespiti compresi nelle tabelle ministeriali; per costruire correttamente un piano di ammortamento di quei pochi beni assoggettati a coefficienti di ammortamento inferiori al 2% annuo, è sufficiente selezionare le celle della riga 59 e copiare verso il basso le formule in esse contenute.

Il modello può essere ulteriormente personalizzato specificando, nella parte alta, i costi imputati direttamente al bene da ammortizzare (costo di acquisto, spese di trasporto, spese di installazione) e sommando questi ultimi nella cella D5.

Come costruire il modello

Nella costruzione del piano di ammortamento si è preferito utilizzare una “struttura” differente rispetto a quella adottata nel modello relativo all’ammortamento ordinario, in maniera tale da offrire al lettore qualche spunto di riflessione sulle “infinite” modalità di utilizzo di un foglio di calcolo. Analizziamolo a partire dalla colonna A.

Figura 2. Piano di ammortamento

Piano di ammortamento

Nella cella A10 è stata utilizzata la formula =SE(G10>0;D6;””) mentre, nella cella A11 la formula =SE(G11>0;A10+1;””); quest’ultima è stata successivamente copiata fino alla cella A59 (il prospetto prevede cinquanta periodi di ammortamento ma è possibile, come vedremo, inserire facilmente ulteriori righe nel caso necessitino).

Le formule utilizzate consentono la trascrizione dell’esercizio contabile di riferimento nelle celle della colonna A se nella corrispondente cella della colonna G è presente un valore maggiore di zero (0).

=> Vai all’ammortamento dei cespiti con Access

Nella cella G10 è stata utilizzata la formula =C10+E10 che consente di calcolare il totale tra i due coefficienti, ordinario e anticipato relativo al primo anno di ammortamento del cespite; la formula è stata copiata nelle due celle sottostanti; nella cella G13 è stata utilizzata la formula =C13 che ripropone il solo coefficiente di ammortamento ordinario (la formula è stata successivamente copiata verso il basso, sempre fino alla riga 59).

Nella cella C10 è stata utilizzata la formula =D7/2 in quanto, in base alla normativa fiscale vigente, il coefficiente di ammortamento ministeriale relativo al primo anno deve essere ridotto alla metà.

Nella cella C11 è stata utilizzata la formula =SE(100%-G10>$D$7;$D$7;100%-G10) che può essere letta in questo modo: se la differenza tra 1 (100%) e la percentuale di ammortamento riferita all’anno precedente (G10) è maggiore del coefficiente di ammortamento ministeriale (è minore di D7), trascrivi quest’ultimo valore (D7), altrimenti trascrivi il valore residuale (100%-G10).

Nella cella C12 è stata utilizzata la formula

=SE(100%-SOMMA($G$10:G11)>$D$7;$D$7;100%-SOMMA($G$10:G11))